The Reliques of Tolti-Aph

An interactive fiction by Graham Nelson (2005) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text		Section 2(b) - The capacity for magic

Memorisation relates various people to various spells. The verb to know (he knows, they know, he knew, it is known) implies the memorisation relation.

Understand "spells" as listing spells. Listing spells is an action applying to nothing. Carry out listing spells: reel off the spells.[1]

After taking inventory: reel off the spells; continue the action.

To reel off the spells:
    say "You have the following spells committed to memory:[line break]";
    repeat through the Table of Enchantments in cost column order[2]
    begin;
        let this spell be the spell entry;
        if the player knows this spell
        begin;
            say " [this spell] ([nature of this spell]): cost [cost of this spell] strength";
            if the requirement of this spell is not air, say ", requires [requirement of this spell]";
            say "[line break]";
        end if;
    end repeat;
    say "[line break]".

Notes

[1]. Like "DIAGNOSE", this command and its consequent action were added to satisfy the nostalgia of the playtesters.

[2]. Each time we need to list the spells known by the player, we are requiring the computer to work out how to look through the table of spells in cost order, which is a little inefficient - but it causes no perceptible delay in play. We don't list the spells in the right order to start with because we can't be bothered, and because it would be problematic when we come to add extension rules later on; and we don't sort the table in cost order at the start of play because we are not allowed to disturb the ordering of a table which defines properties attached to values.