The Reliques of Tolti-Aph
An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Contents
Previous
Next
Complete text
The Archive Chamber is a room. "A cellar, but hardly the cellar of an inn: that must have been a subterfuge. Here were stored the knowledge of spells of particular power or importance, those the possessors did not want to entrust to mere scrolls. Once coffins lined both sides of this room, but most are broken and empty, the inhabitants turned to dust: in some cases quite recently, since they broke your fall.
The single remaining coffin, sealed up by magical, half-transparent wood, contains a motionless figure."
The broken coffins are scenery in the Archive Chamber. The description is "Their seals are broken and their contents dust." Effect of casting mend at the broken coffins: record outcome "but cannot restore the many layers of ancient magic that sustained these intact"; rule succeeds. The broken coffins are wood.
The pair of infravision spectacles is in the Archive Chamber. "Dislodged by your fall, perhaps, a pair of infravision spectacles lies on the stone floor, the skull that once wore them being now only powder." The description of the spectacles is "You see nothing special about the infravision spectacles. No, really, you never did see anything special in them. Okay, so darker-leaning magic users liked to wear them around town in an I'm-too-cool-for-sunlight pose, but really." The spectacles are wearable. After looking when in darkness and the player is wearing the infravision spectacles, say "It's actually a myth that infravision spectacles enable you to see in the dark. They actually allow you to see light re-phasing around magical surfaces." The infravision spectacles are metal.
The single remaining coffin is transparent closed scenery in the Archive Chamber. It contains a motionless figure. The figure is a woman. The figure knows summon elemental. The description of the motionless figure is "Her face is hatchet-like, her brows straight in a way you have seen only in statues. But she breathes. Very slowly, but she breathes." Instead of opening the coffin, say "It is sealed with a powerful magic, protecting the life within." Instead of entering the coffin, say "Standing on the coffin would take you no nearer the ceiling, in real terms, and as for entering it, the thing is shut tight: quite apart from any considerations of human decency." The single remaining coffin is wood.
Instead of going up in the Archive Chamber, say "There is no apparent way of climbing up to the square hole in the vaulted ceiling of this cellar." Instead of going nowhere from the Archive Chamber, say "You explore each corner of the cellar, hoping to find a way out. But it is very well secured against infestation, ground-water, thieves and the like."
In the Archive Chamber is scenery thing called the square hole in the vaulted ceiling. The description of the square hole is "Through the square hole in the ceiling, you are tantalised by the fine afternoon sunshine: that etherial, simple perfection which is somehow appreciated only by those who see it from a prison cell." Understand "door" and "trap" and "trap-door" and "trapdoor" as the square hole. The square hole is air.
The Prison Visit is a scene. The Prison Visit begins when the player is in the Archive Chamber for the ninth turn. The Prison Visit ends when the player is not in the Archive Chamber.
Table of Prison Visit Noises Off
| noise message |
| "Just as you are thinking that being imprisoned down here is no life for a young magic-user with so much to give (i.e., so much to take), you think you might hear a faint noise from above." |
| "No, it must have been nothing." |
| "That second faint noise must have been nothing too." |
| "Possibly all that masonry is re-settling itself." |
| "You begin to conjure up a mental picture of some ideal rescuer, padding about through the rubble up above, and about to stumble upon you." |
| "A rescuer. Absolutely. Let's see. Nice smile, healthy outdoor tan perhaps, hint of sparkling excitement in the eyes, forty feet of rope and a grappling hook coiled over one shoulder. A bit in awe of magic-users, for preference. Yes, that would do very nicely about now." |
| "Well, the noises bump on. Sounds almost like pacing, in fact." |
| "Is it your imagination? Or could that be the sound of breathing?" |
| "Come to think of it, the thought of this imminent meeting makes you a little nervous. You fuss with your hair, look down at your fingernails, wince." |
| "Any minute now. It'll be like one of those romantic-adventure poems. You'll trek off into the wilderness together." |
| "That is, you'll trek off together if anything ever happens." |
| "Oh, when is that divine smile going to appear at the hole in the ceiling?" |
| "Ah, such a metaphor for life, this." |
| "Tum te tum. Tum tum te-tum." |
Understand the commands "yell" and "holler" as "answer". Answering is making a rumpus. Singing is making a rumpus. Asking someone for something is making a rumpus. Instead of making a rumpus during the Prison Visit, say "No matter how loudly you call out, the sound seems to be deadened by the funereal walls of this burial chamber."
Every turn during the Prison Visit:
repeat through the Table of Prison Visit Noises Off
begin;
say "[noise message entry][paragraph break]";
blank out the whole row;
stop;
end repeat.[1]
Effect of casting web at the square hole:
if Prison Visit is happening, record outcome "but although a plausible spider's-web does drape itself across the hole for a while, it obviously wasn't spectacular enough to get the attention of the mysterious person above";
otherwise record outcome "but although a plausible spider's-web does drape itself across the hole for a while, it doesn't last, and doesn't by any means hang a useful thread down to your level";
rule succeeds.
Effect of casting magic missile at the square hole:
if Prison Visit is happening
begin;
record outcome "and a spectacular firework of a missile is fired into the afternoon air. It must get the attention of anyone around, surely? And your heart surges as one end of a forty-foot coil of rope is thrown down, and a vague shape from above gives a muffled yell, and you step onto the grappling hook to be pulled up, up, above the old coffins and over the lip of the trap-doorway to...
Oh, well, isn't that just [italic type]exactly[roman type] like life? You leap backwards. So does your benefactor. The trap-door slams angrily shut, swallowing the rope as if it were so much spaghetti";
record event the rescued from the archive rule;
otherwise;
record outcome "and a spectacular firework of a missile is fired into the afternoon air. It must get the attention of anyone around, surely? But then, in a ruined city, who's to see it";
end if;
rule succeeds.
Instead of listening during Prison Visit, say "The trouble is, the harder you concentrate on listening, the more you hear your own heartbeat and breathing."
Glog the Troll is a cave troll.[2]
This is the rescued from the archive rule:
now the trap-door is closed;
now the trap-door is locked;
move Glog to the Old School;
now Glog is surprised;
move the player to the Old School.