The Reliques of Tolti-Aph

An interactive fiction by Graham Nelson (2005) - the Inform 7 source text

Home page

Contents
Previous
Next

Complete text		Section 1(e) - Experience and levels

A person has a number called level. The level of a person is usually 1.[1]

Table of Level Advancement
level number   experience points to progress
1   50
2   100
3   250
4   600
5   0

Every turn:
    let the current level be the level of the player;
    if the current level is 5, stop;
    let the target be the experience points to progress corresponding to a level number of the current level in the Table of Level Advancement;
    if the score is greater than the target
    begin;
        say "You progress to level [current level plus 1]!";
        increase the level of the player by 1;
    end if.

Procedural rule: ignore the announce the score rule.[2]

Carry out requesting the score:
    say "You are a level [level of the player] magic-user, with [score] experience point[s]. ";
    let the current level be the level of the player;
    let the target be the experience points to progress corresponding to a level number of the current level in the Table of Level Advancement;
    let the target be the target minus the score;
    if the current level is 5, say "It is not possible to progress further." instead;
    if the target <= 0, say "You will soon progress to the next level." instead;
    say "You need [target] [if the score > 0]more [end if]point[s] to progress to the next level." instead.

When play begins, change the right hand status line to "LVL: [level of the player] STR: [strength of the player]".[3]

Notes

[1]. RPGs seem to like the idea of numbered levels, with a level 3 magic-user that bit more puissant than a level 2 one. I suppose this may derive from the vague sense of mystery swirling around the "degrees" of masonic lodges, the Benevolent and Protective Order of the Elks, and such.

[2]. This is the built-in rule which ordinarily handles SCORE commands. We need to throw it out because we are somewhat subverting the usual conventions by using the score to represent the total accumulated experience points of the player; which means we need to write our own rule to tell the player his current score, as follows.

[3]. One becomes weaker by performing magic or being wounded, stronger by resting or being healed; one gains experience by living a busy life. These tallies matter a lot, so we make them prominently visible at all times on the status line - the bar at the top of the screen.