The Reliques of Tolti-Aph
An interactive fiction by Graham Nelson (2005) - the Inform 7 source text
Contents
Previous
Next
Complete text
Section W(a) - Cure baldness, mindsift and corrode
[The four quarters are in effect independent scenarios, but there's a certain amount of cross-talk: the new spells found in each quarter have to have interesting effects on the items and things in the other quarters. Here, at any rate, we create two new W&W monsters, and three new W&W spells.]
Table of Monstrous Beasts (continued)
| name | strength | hand-to-hand combat method | unarmed combat hit dice | defensive charm |
| reptile | 5 | "striking at you" | 1d6 | |
| priest | 12 | "jabbing you with martial artistry" | 1d6 |
Table of Enchantments (continued)
| spell | nature | cost | requirement | emission | targeting | duration | duration timer | usage count |
| mindsift | arcana | 6 | metal | "a tracery of silver lines" | targeted | -- | ||
| cure baldness | healing | 4 | flesh | "citrus-scented steam" | targeted | |||
| corrode | offensive | 4 | wood | "dense fog" | targeted |
Effect of casting cure baldness at something:
record outcome "but goes out again without achieving much more than a passing aroma of lemons";
rule succeeds.
Effect of casting cure baldness at a person:
record outcome "but passes again without noticeable effect - these spells never work";
rule succeeds.
Effect of casting cure baldness at a werespider:
record outcome "- a patently foolish proceeding considering that these things are hairy enough already";
rule succeeds.
Effect of casting mindsift at something:
record outcome "leaving you with a brief, soothing amnesia before your life presses back into your mind";
rule succeeds.
Effect of casting mindsift at skeleton:
record outcome "and, to your surprise, find there a faint residue of that last fading desire to live - but without breath, memory does not last, and nothing more reaches you";
rule succeeds.
Effect of casting mindsift at goblin lord:
record outcome "but there is nothing specific left, only a burning sensation of singular unpleasantness";
rule succeeds.
Effect of casting mindsift at a wyvern:
record outcome "and are treated to a rapid succession of simple but powerful sensations - flying, lazing in a hot sun, a scorching heat in your throat. No magic, though";
rule succeeds.
Effect of casting mindsift at the succubi:
record outcome "but the memories are your own - if with a bit more sensation than you can usually summon up by just thinking about it. You feel suddenly warm";
rule succeeds.
Effect of casting mindsift at the copper-scaled snake: now the player knows corrode; record outcome "extracting its recollections, simplified by its reptile brain: anger, and a much-decayed memory of the ruination spell it cast here in revenge - which, however decayed, seems to be yours now";
rule succeeds.
Effect of casting mindsift at a person:
repeat through Table of Enchantments
begin;
if the second noun knows the spell entry and the player does not know the spell entry
begin;
let the extracted spell be the spell entry;
now the player knows the extracted spell;
record outcome "and from the whirling mass of thoughts you clutch hold of something powerful and unfamiliar";
rule succeeds;
end if;
end repeat;
record outcome "but there is nothing magical you can extract from that sudden rush of thoughts";
rule succeeds.
Effect of casting corrode at something metal:
record outcome "which now looks a little redder";
rule succeeds.
Effect of casting corrode at a portable metal thing:
remove the second noun from play;
record outcome "which rusts through and vanishes";
rule succeeds.
Effect of casting corrode at a weapon when the weapon is not metal:
record outcome "but doesn't do much damage because the weapon is not mostly made of metal";
rule succeeds.
Effect of casting corrode at a person:
record outcome "causing [the second noun] to break out in freckles";
rule succeeds.