Damnatio Memoriae
An interactive fiction by Emily Short (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
After printing the player's obituary: follow the summation rules.
The summation rules is a rulebook.
A summation rule:
if Julia is apparently guilty
begin;
say "This all could have worked out better for [Julia]; inspired by [the random thing which incriminates Julia], Tiberius takes out his wrath on her, and she ends up starving at Rhegium, unable to supply herself with food, for all her arts.";
end if.
A summation rule:
if Germanicus is apparently guilty
begin;
say "[Germanicus] has an uncomfortable time with the guilt you implied for him with [the random thing which incriminates Germanicus]; the native suspicion of Tiberius, and the popularity of Germanicus with the army, have already made his position less secure; and within a few years he has died under mysterious circumstances.";
end if.
A summation rule:
if Clemens is apparently guilty and Clemens is whole
begin;
if Clemens protects the player and the player protects Clemens
begin;
if the player is apparently guilty
begin;
say "You had some vague hopes that [the random thing which incriminates Clemens] would cause Clemens to be thrown in prison alongside you, in which case you could plan your escape together. But this does not happen, and you have no way of knowing what is happening to him, other than that, since you're alive, he must be as well.";
otherwise;
say "[Clemens], despite being innocent in fact, is sentenced to be executed because of [the random thing which incriminates Clemens]: Tiberius decides, unreasonably, that he must be the product of some infidelity on the part of one of your family. (This impression is increased because he looks so very much like you, reverse-linked.) Things only get stranger when they try to execute him but fail. The last you hear, he's relegated to a temple under heavy guard, while Tiberius tries to decide whether he is an evil omen, or a god in disguise, or...";
end if;
otherwise;
say "[Clemens], despite being innocent in fact, is executed because of [the random thing which incriminates Clemens]: Tiberius decides, unreasonably, that he must be the product of some infidelity on the part of your mother, or possibly something even more sinister, and thus bear a dangerous amount of the imperial Art.";
end if;
end if.
To decide whether player croaked:
(- (deadflag == 1) -);
A summation rule:
if player croaked, make no decision;
if the soldiers can see the corpse
begin;
say "You do get to feeling bad about Clemens, who was wretched company and a drinker, not to mention disobedient and slothful -- but still, the only person you had to talk to hereabouts.";
end if.
A summation rule:
if the Phaenomena is ruined
begin;
say "Your [Phaenomena] is lost to the world, and this is a serious pity -- it was good work, and good scholarship, and there are few with your skill who have any interest in such undertakings now.";
end if;
if the soldiers can see the Phaenomena and something (called the master) protects the Phaenomena
begin;
say "As for your [Phaenomena], it is taken back to Rome and published, though under the name of [a random other person mentioned by the master].";
end if;
if the Phaenomena is whole and the Phaenomena incriminates the player
begin;
say "Your [Phaenomena] does survive, and with its proper attribution and the original account you made detailing how it was done. Surely history will remember that about you.";
end if;
To say start:
if started printing is 0, say line break;
change started printing to 1;
The last endgame rule:
end the game in victory;
rule succeeds;
Some soldiers are a man. "The soldiers are all standing around looking at you in a highly unpleasant manner."