Damnatio Memoriae
An interactive fiction by Emily Short (2008) - the Inform 7 source text
Contents
Previous
Next
Complete text
Understand "attack [something] with [something preferably held]" as attacking it with.
Attacking it with is an action applying to one thing and one carried thing.
Check attacking it with:
if the second noun is the lamp, try burning the noun instead;
if the second noun is a paper, say "[The second noun] is a very ineffective bludgeon." instead;
if the second noun is a book, say "[The second noun] is not yet weighty enough to be any use in that sense." instead;
Carry out attacking it with:
try attacking the noun.
Understand "rip [something]" or "rip up [something]" or "rip [something] up" as attacking.
Understand the commands "tear" or "shred" as "rip".
Instead of attacking a paper:
say "You rip [the noun] to shreds.";
destroy the noun.
Instead of attacking something fragile:
say "You smash [the noun].";
destroy the noun.
A thing has some text called shattering description. The shattering description of a thing is usually "shatters under an invisible blow, and the link dies with it".
Understand the commands "kill" and "attack" and "murder" and "destroy" as something new. Understand "kill [someone]" as killing. Understand "kill [something]" as killing. Understand the commands "murder" and "destroy" and "attack" as "kill".
Killing is an action applying to one thing. Instead of killing a thing which is not a person, try attacking the noun. Carry out killing: say ""
Instead of attacking the player when Clemens protects the player:
say "You hit yourself. It does hurt, but you suspect Clemens gets the brunt of it."
Instead of attacking the player:
if the player affects Clemens, say "You punch yourself in the thigh, which is not a very edifying process. If Clemens feels anything, you receive no sign of it.";
otherwise say "You hit yourself, which does hurt, but accomplishes no useful purpose. Killing yourself, now, that would require a bit more focus."
Instead of killing the player:
if Clemens protects the player, say "You make some attempts to slit your wrists, but the blood just flows and flows." instead;
if the player affects Clemens
begin;
say "You attack yourself; it is Clemens who dies.";
destroy Clemens;
otherwise;
say "Seeing no honorable and unembarrassing way out of your predicament, you open your veins, and are soon free from earthly cares.";
end the game in death;
end if.
Instead of attacking something sturdy:
say "[The noun] is not so easily destroyed."
Instead of attacking something fragile which affects something important (called the slave):
if the slave is sturdy and the slave protects the noun, say "[The noun] resists smashing, thanks to its link with [the slave]." instead;
if the slave affects the noun
begin;
say "[The noun] shatters.";
destroy the noun;
if the slave is visible, say line break;
end if;
if the slave is visible, say "[The slave] [shattering description of the slave].";
destroy the slave;
if the noun is ruined, say line break.